INDICADOR KONCORDE PARA METASTOCK

Foro sobre el famoso programa de gráficos de Equis.
pilotovaliente
Mensajes: 8
Registrado: 25 Jun 2020 19:56

Re: INDICADOR KONCORDE PARA METASTOCK

Mensaje por pilotovaliente »

Hay un error en la lÍnea donde está "MIESTOCASTICO", donde aparece "c" deberia aparecer "MIPRECIO".
El código correcto es:

MIESTOCASTICO:=(sum(MIPRECIO-(llv(l,21)),3)/sum(hhv(h,21)-llv(l,21),3))*100;
pilotovaliente
Mensajes: 8
Registrado: 25 Jun 2020 19:56

Re: INDICADOR KONCORDE PARA METASTOCK

Mensaje por pilotovaliente »

Éste sería su aspecto una vez configurada la plantilla.
Adjuntos
Aspecto Koncorde.jpg
pilotovaliente
Mensajes: 8
Registrado: 25 Jun 2020 19:56

Re: INDICADOR KONCORDE PARA METASTOCK

Mensaje por pilotovaliente »

Si a alguien le interesa descargarlo, tiene el link al final del siguiente post.
Última edición por pilotovaliente el 21 Ago 2020 01:38, editado 1 vez en total.
pilotovaliente
Mensajes: 8
Registrado: 25 Jun 2020 19:56

Re: INDICADOR KONCORDE PARA METASTOCK

Mensaje por pilotovaliente »

Hola de nuevo.
He modificado un poco el codigo, para depurar errores.
Y he añadido una mejora: ahora se puede modificar el periodo de la media roja.


{Koncorde_1}
{Linea Marron: "MONTAÑA"}
MIMFI:=mfi(14);
MIPRECIO:=(o+c+h+l)/4;
OB1:=(bbandtop(MIPRECIO,25,S,2)+bbandbot(MIPRECIO,25,S,2))/2;
OB2:=bbandtop(MIPRECIO,25,S,2)-bbandbot(MIPRECIO,25,S,2);
BOLLOSC:=((MIPRECIO-OB1)/if(OB2=0,0.0001,OB2))*100;
MIRSI:=rsi(MIPRECIO,14);
MIESTOCASTICO:=(sum(MIPRECIO-(llv(l,21)),3)/if(sum(hhv(h,21)-llv(l,21),3)=0,0.0001,sum(hhv(h,21)-llv(l,21),3)))*100;
MARRON:=(MIRSI+MIMFI+BOLLOSC+(MIESTOCASTICO/3))/2;
MARRON;

{Koncorde_2}
{Linea Verde: "MANOS DEBILES"}
MIPVI:=pvi(c);
PVIMED:=mov(MIPVI,15,e);
PVIMAX:=hhv(PVIMED,90);
PVIMIN:=llv(PVIMED,90);
MIVERDE:=((MIPVI-PVIMED)*100)/if((PVIMAX-PVIMIN)=0,0.0001,(PVIMAX-PVIMIN));
VERDE:=Fmlvar("Koncorde_1","MARRON")+MIVERDE;
VERDE;

{Koncorde_3}
{Linea Azul: "MANOS FUERTES"}
MINVI:=nvi(c);
NVIMED:=mov(MINVI,15,e);
NVIMAX:=hhv(NVIMED,90);
NVIMIN:=llv(NVIMED,90);
AZUL:=(MINVI-NVIMED)*100/if((NVIMAX-NVIMIN)=0,0.0001,(NVIMAX-NVIMIN));
AZUL;

{Koncorde_4}
{Linea Roja: "MEDIA de la MONTAÑA"}
MIMEDIA:=Input("Periodos Media",1,90,15);
Mov(Fmlvar("Koncorde_1","MARRON"),MIMEDIA,e);


Adjunto en la descarga el indicador y la plantilla, junto con las intrucciones de instalacion de ambos.
Adjuntos
Koncorde_MetaStock.rar
(181.43 KiB) Descargado 12 veces
Última edición por pilotovaliente el 11 Sep 2020 22:07, editado 2 veces en total.
pilotovaliente
Mensajes: 8
Registrado: 25 Jun 2020 19:56

Re: INDICADOR KONCORDE PARA METASTOCK

Mensaje por pilotovaliente »

pitufogranjero escribió: 21 Ago 2008 13:57 yo estoy llevando el vigia al metastock, si alguien puede ayudar, que se apunte...
{Adaptacion de ProRealTime_BLAI5_VIGIA_v.09 a MetaStock}

{Vigia_1}
{"VIGIA"}
MIMFI:=mfi(20);
MIPRECIO:=(o+c+h+l)/4;
OB1:=(bbandtop(MIPRECIO,20,s,2)+bbandbot(MIPRECIO,20,s,2))/2;
OB2:=bbandtop(MIPRECIO,20,s,2)-bbandbot(MIPRECIO,20,s,2);
BOLLOSC:=((c-OB1)/if(OB2=0,0.0001,OB2))*100;
MIRSI:=rsi(MIPRECIO,21);
MIESTOCASTICO:=(sum(MIPRECIO-(llv(l,20)),3)/if(sum(hhv(h,20)-llv(l,20),3)=0,0.0001,sum(hhv(h,20)-llv(l,20),3)))*100;
VG:=((MIRSI+MIMFI+BOLLOSC+(MIESTOCASTICO/3))/2)-60;
VG;

{Vigia_2}
{"Media de VIGIA"}
MIMEDIA:=input("Periodos Media Vigia",1,90,20);
MEDIAVIGIA:=mov(fmlvar("Vigia_1","VG"),MIMEDIA,e);
MEDIAVIGIA;

{Vigia_3}
{"FILTRO"}
HISTVG:=fmlvar("Vigia_1","VG")-fmlvar("Vigia_2","MEDIAVIGIA");
HISTAV:=wilders(HISTVG,20);
HISTAV;

{Vigia_4}
{"BANDAS VARIABLES"}
BANDAMEDIAVG:=mov(fmlvar("Vigia_1","VG"),70,s);
BANDASUPERIORVG:=BANDAMEDIAVG + stdev(fmlvar("Vigia_1","VG"),70);
BANDAINFERIORVG:=BANDAMEDIAVG - stdev(fmlvar("Vigia_1","VG"),70);
BANDASUPERIORVG;
BANDAINFERIORVG;

{Vigia_5}
{"ASTRO"}
ASTRO:=(mov(fmlvar("Vigia_1","VG"),8,S)-mov(wilders(fmlvar("Vigia_1","VG"),19),6,e))*.44;
ASTRO1:=if(ASTRO<0,ASTRO,0);
ASTRO2:=if(ASTRO>0,ASTRO,0);
ASTRO1;
ASTRO2;
Adjuntos
vigia.rar
(4.9 KiB) Descargado 6 veces
vigia-.jpg
pilotovaliente
Mensajes: 8
Registrado: 25 Jun 2020 19:56

Re: INDICADOR KONCORDE PARA METASTOCK

Mensaje por pilotovaliente »

He adaptado el BLAI5_VPM_2.0 de ProRealTime a MetaStock, para añadirlo al VIGIA.
pilotovaliente
Mensajes: 8
Registrado: 25 Jun 2020 19:56

Re: INDICADOR KONCORDE PARA METASTOCK

Mensaje por pilotovaliente »

{Adaptacion de ProRealTime_BLAI5_VPM_2.0 a MetaStock}
{Volumen Proporcional Medio 2.0 de Blai5 para deteccion de puntas de volumen}

F:=35;
VOLMAX:=hhv(v,90);
MIVOL:=(v*100/VOLMAX)*4/5;
VOLMED:=mov(MIVOL,20,e);
VPM:=MIVOL-VOLMED;
VPM1:=if(VPM>0,VPM,0);
VPM2:=if(VPM<0,VPM,0);
VPM1;
VPM2;
AL:=if(VPM>F,VPM,0);
AL;
Responder

Volver a “Metastock”