sobre el scalping

[jchopinn]

He leido un articulo que se publico aqui en X-trader hacer un tiempo acerca del scalping.
Copio y pego lo siguiente , que es una de las técnicas descritas en el citado artículo:

"Scalping en el rango de apertura de 15 minutos
Este es uno de mis métodos favoritos: es sencillo, sólo requiere tener un acceso rápido a la plataforma de nuestro broker y es muy fiable. Difiere de las clásicas estrategias de rotura del rango de apertura clásicas en que los beneficios son cazados rápidamente, por lo que la operación no dura más de 1 minuto.

Patrón: Simplemente debemos esperar 15 minutos desde la apertura del mercado y anotar el máximo y el mínimo que se han producido en ese periodo.
Reglas de Entrada: Situamos un stop de compra 2 ticks por encima del máximo y un stop de venta 2 ticks por debajo del mínimo.
Objetivo: Cerramos la posición cuando tengamos un punto entero de beneficio (4 ticks del S&P 500)
Stop Loss: Situaremos el stop a una distancia de un punto entero desde el precio de entrada. También cerraremos la posición si permanecemos en mercado más de 1 minuto.
Re-Entrada: si nos salta el stop loss, buscaremos la entrada en el lado opuesto del rango, doblando la posición"



Mi pregunta es sobre la estrategia porque no la acabo de entender, dice que espera 15 min anota mx y min. luego situa un stop de compra un stop de compra y venta de 2 ticks por encima y debajo del mx y min. No entiendo esta parte, a que llama tick? porque a 2 puntos no se refiere..., porque luego dice cerramos cuando tengamos 1 punto de beneficio.. Y luego situa el stop a la distancia de 1 punto de la entrada..

A ver si alguien que haga scalping de vez en cuando me puede aclarar esto
saludos

[Rockola-Dance]

El tick para el sp es de 0.25 sube o baja de 0.25 en 0.25 por lo tanto 1 punto corresponde a 4 ticks de 0.25 = 1 punto xr sp500

[Rockola-Dance]

El tick para el sp es de 0.25 sube o baja de 0.25 en 0.25 por lo tanto 1 punto corresponde a 4 ticks de 0.25 = 1 punto xr sp500

[jchopinn]

Y como puede meter 1 stop de compra y uno de venta? porque haciendo scalping eso va muy rapido para poder hacer esto, o que'?

[geoffbond007]

Y como puede meter 1 stop de compra y uno de venta? porque haciendo scalping eso va muy rapido para poder hacer esto, o que'?

No pierdas tu tiempo.. la gente tiene una negacion tremenda en aceptar que No es posible hacer scalp a nivel; retail Y es capaz de hasta de insultar... prefieren creele a vendedores ciberneticos,, como gente como esta es que hacen el price action crudo y puro una virtud...

que se jodan..

NO es posibkle hacer scalp Online y menos en Forex.. Quien diga lo contrario es un ladron!!!

[jchopinn]

Entonces a ti por la forma de expresarte parece ser que el scalping no te va mucho y piensas que no puedes ganar nada practicando esta técnica, es asi?

[Virgilio]

Aquí está el código en EasyLanguage para este sistema:

inputs: HoraInicioSR(1530), HoraFinalSR(1545), MargenEntradaEnTicks(2), StopProfitEnTicks(4), StopLossEnTicks(4), MinuFromEntryForExit(1);

vars: oSoporte(0), oResistencia(0), NoEntradasLargas(0), NoEntradasCortas(0), HoraEntradaMas1Minut(2400),

LanzarOrdenLargos(0), LanzarOrdenCortos(0), PosicionBarAnterior(0), SalirPorSLlargos(False), LanzarOrdenLargos2(0), HoraUltimaDia(2145),

LanzarOrdenCortos2(0), SalirPorSLcortos(False), oResistenciaAnterior(0), oSoporteAnterior(0), PrecioEntrada(0);

Value1 = SOPORTESRESISTENCIAS(HoraInicioSR, HoraFinalSR, oSoporte, oResistencia);

// PARA SABER EL PRECIO DE ENTRADA:

If Marketposition <> 0 and BarsSinceEntry = 0 then PrecioEntrada = EntryPrice;

// PARA IMPEDIR REENTRAR LARGOS Y CORTOS MAS DE UNA SOLA VEZ:

if LanzarOrdenLargos2 =1 and High >= oResistenciaAnterior + MargenEntradaEnTicks * MinMove/PriceScale then SalirPorSLlargos = False;

if LanzarOrdenCortos2 =1 and Low <= oSoporteAnterior - MargenEntradaEnTicks * MinMove/PriceScale then SalirPorSLcortos = False;


// REINICIALIZACIÓN A CERO DE LA ORDEN DE REENTRADA LANZADA:

LanzarOrdenLargos2 = 0;
LanzarOrdenCortos2 = 0;

// SUBRUTINA PARA CONTAR LAS VECES QUE HEMOS ENTRADO LARGOS Y CORTOS:

if LanzarOrdenLargos =1 and High >= oResistenciaAnterior + MargenEntradaEnTicks * MinMove/PriceScale then

Begin

NoEntradasLargas = NoEntradasLargas + 1;
SalirPorSLcortos = False; //Al entrar Largos, ya no podemos volver a reentrar Cortos.

end;

If LanzarOrdenCortos =1 AND low <= oSoporteAnterior - MargenEntradaEnTicks * MinMove/PriceScale then

begin

NoEntradasCortas = NoEntradasCortas + 1;
SalirPorSLlargos = False; //Al entrar Cortos, ya no podemos volver a reentrar largos.

end;

{ Si no tuviesemos que distinguir entre entradas largas y cortas, bastaría con la función EntriesToday }

// REINICIALIZACIÓN A CERO DE LA ORDEN LANZADA: Esta órdenes deben desaparecer se hayan ejecutado o no.

LanzarOrdenLargos = 0;
LanzarOrdenCortos = 0;


// PARA REINICIAR EL NÚMERO DE ENTRADAS DIARIAS LARGAS Y CORTAS a CERO:

If Date[1]<>Date then

Begin
HoraUltimaDia = T[1];
NoEntradasLargas = 0;
NoEntradasCortas = 0;
SalirPorSLlargos = False;
SalirPorSLcortos = False;

End ;

//Ticks En Puntos = MinMove/PriceScale........ Ticks en dinero = ( MinMove/PriceScale ) * BigPointValue

// ENTRADA POR RUPTURA DE SOPORTES Y RESISTENCIAS A PARTIR DE UNA HORA DETERMINADA (ENTRAMOS UNA SOLA VEZ LARGOS Y CORTOS):

If Marketposition<>1 and T >= HoraFinalSR AND T< HoraUltimaDia and NoEntradasLargas = 0 then

begin

buy ("Largos") 1 contract next bar at oResistencia + MargenEntradaEnTicks * MinMove/PriceScale STOP;
LanzarOrdenLargos = 1;

End ;

If Marketposition<>-1 and T >= HoraFinalSR AND T< HoraUltimaDia and NoEntradasCortas = 0 then

begin

sell short("Cortos") 1 contract next bar at oSoporte - MargenEntradaEnTicks * MinMove/PriceScale STOP;
LanzarOrdenCortos = 1;

end;

// SALIDA POR STOP PROFIT FIJO DE "X" TICKS:

// SetProfitTarget( StopProfitEnTicks * MinMove/PriceScale ); Con esta instrucción no sabemos el orden de entrada y salida en la misma barra en backtesting salvo que tengamos suficienttes datos tick a tick.

If MARKETPOSITION=1 THEN SELL ("Stop profit largos") 1 CONTRACT NEXT BAR AT ENTRYPRICE + StopProfitEnTicks * MinMove/PriceScale LIMIT;

If MARKETPOSITION=-1 THEN BUY TO COVER ("Stop profit cortos") 1 CONTRACT NEXT BAR AT ENTRYPRICE - StopProfitEnTicks * MinMove/PriceScale LIMIT;
{
POSICION LARGA ---> PRECIO SALIDA >= Entryprice + StopProfitEnTicks * MinMove/PriceScale
POSICION CORTA ---> PRECIO SALIDA <= Entryprice - StopProfitEnTicks * MinMove/PriceScale
}

// SALIDA POR STOP LOSS FIJO DE "X" TICKS:

// SetStopLoss(StopLossEnTicks * MinMove/PriceScale ); Con esta instrucción no sabemos el orden de entrada y salida en la misma barra en backtesting salvo que tengamos suficienttes datos tick a tick.

If MARKETPOSITION=1 THEN SELL ("Stop loss largos") 1 CONTRACT NEXT BAR AT ENTRYPRICE - StopLossEnTicks * MinMove/PriceScale STOP;

If MARKETPOSITION=-1 THEN BUY TO COVER ("Stop loss cortos") 1 CONTRACT NEXT BAR AT ENTRYPRICE + StopLossEnTicks * MinMove/PriceScale STOP;
{
POSICION LARGA ---> PRECIO SALIDA <= Entryprice - StopLossEnTicks * MinMove/PriceScale
POSICION CORTA ---> PRECIO SALIDA >= Entryprice + StopLossEnTicks * MinMove/PriceScale
}


// SALIDA AL CABO DE 1 MINUTO DE HABER ENTRADO:

HoraEntradaMas1Minut = MinutesToTime( TimeToMinutes(EntryTime) + MinuFromEntryForExit );

If Marketposition = 1 and Time>= HoraEntradaMas1Minut then sell ("Exit Long 1 Min") 1 contract on this bar on close;

If Marketposition = -1 and Time>= HoraEntradaMas1Minut then buy to cover ("Exit Short 1 Min") 1 contract on this bar on close;

// SÓLO SI SE TOCA EL STOP LOSS --------> REENTRAMOS EN EL NIVEL OPUESTO AL DE ENTRADA:

{Si en la barra anterior estábamos Largos y ahora estamos fuera del mercado ------> Hemos salido de Largos:

si hemos salido a un Precio <= EntryPrice - StopLossEnTicks * MinMove/PriceScale * BigPointValue ---> hemos salido por Stop Loss.

OJO: la posibilidad de entrar Cortos anula la posible reentrada larga pues ya no sería una reentrada larga la posterior entrada larga:

si pudiendo reentrar largos, entramos Cortos, se debe anular la posibilidad de reentrar largos }


If PosicionBarAnterior = 1 and MarketPosition = 0 and Low <= PrecioEntrada - StopLossEnTicks * MinMove/PriceScale then
{ Marketposition = 0 and BarsSinceExit = 0 }

SalirPorSLlargos = True;

{Si en la barra anterior estábamos Cortos y ahora estamos fuera del mercado ------> Hemos salido de Cortos:

si hemos salido a un Precio >= EntryPrice + StopLossEnTicks * MinMove/PriceScale * BigPointValue ---> hemos salido por Stop Loss.

OJO: la posibilidad de entrar Largos anula la posible reentrada Corta pues ya no sería una reentrada Corta la posterior entrada Corta:

si pudiendo reentrar Cortos, entramos Largos, se debe anular la posibilidad de reentrar Cortos }

If PosicionBarAnterior =-1 and MarketPosition = 0 and High >= PrecioEntrada + StopLossEnTicks * MinMove/PriceScale then
{ Marketposition = 0 and BarsSinceExit = 0 }

SalirPorSLcortos = True;

// REENTRAR LARGOS/CORTOS:

If SalirPorSLlargos =True and Marketposition = 0 and T >= HoraFinalSR and T< HoraUltimaDia then

begin

buy ("Largos2") 1 contract next bar at oResistencia + MargenEntradaEnTicks * MinMove/PriceScale STOP;
LanzarOrdenLargos2 = 1;

end;

If SalirPorSLcortos =True and Marketposition = 0 and T >= HoraFinalSR and T< HoraUltimaDia then

begin

Sell short ("Cortos2") 1 contract next bar at oSoporte - MargenEntradaEnTicks * MinMove/PriceScale STOP;
LanzarOrdenCortos2 = 1;

end;

// DEFINICIÓN DEL RESTO DE VARIABLES:

PosicionBarAnterior = MarketPosition;

oResistenciaAnterior = oResistencia;

oSoporteAnterior = oSoporte;

--------------------------------------------------------------------------------------------------------------------------------

Código de la función SOPORTESRESISTENCIAS :

inputs: HoraInicioSR(NumericSimple), HoraFinalSR(NumericSimple), oSoporte(NumericRef), oResistencia(NumericRef);

// PARA INICIALIZAR EL SOPORTE Y LA RESISTENCIA:

If Time = HoraInicioSR THEN

Begin
oResistencia = H ;
oSoporte = L ;

end;

// VARIACIÓN DEL SOPORTE Y LA RESISTENCIA DENTRO DE LA FRANJA HORARIA:

If Time > HoraInicioSR and Time <= HoraFinalSR then

Begin

If H > oResistencia then oResistencia = H;
If L < oSoporte then oSoporte = L;

end;

SOPORTESRESISTENCIAS= 0;


Un saludo.

[Johnysurf]

Y que tal funciona en Backtest?