indicador cruce de emas con alertas

[rivalera]

saludos recurro ante usteds solicitando ayuda, ya que soy muy nuevo en el tema, la idea es crear un indicador de mas de 8,18, y 200 periodos, pero necesito me genere una alerta o alrma cada vez que se crucen las emas de 8 y 18, tengo un codigo en el que me muestra las emas sin problemas, pero no me genera las alarmas de cruce no se por que , alguien podriua por ayudarme a que esto funcione, le comparto el codigo y quedo al pendiente de sus respuestas, gracias de antemano
//EMAS CRUCE by RV
//@version=4
study(title="EMAS RV", shorttitle="EMAS RV", overlay=true)
len = input(8, minval=1, title="EMA Azul (8)")
src = input(close, title="Cerrada")
out = ema(src, len)
plot(out, color=#2facc0, transp=0, linewidth=3, title="EMA Azul 8")

len2 = input(18, minval=1, title="EMA Roja (18)")
src2 = input(close, title="Cerrada")
out2 = ema(src2, len2)
plot(out2, color=#f19d1f, transp=0, linewidth=3, title="EMA Roja 18")

len3 = input(200, minval=1, title="EMA Blanca 200")
src3 = input(close, title="Cerrada")
out3 = ema(src3, len3)
plot(out3, color=#fcfdf4, transp=0, linewidth=3, title="EMA 200 C4L")

// Alertas de cruce de EMAs
bullishCross = cross(out, out2)
bearishCross = cross(out2, out)
alertcondition(bullishCross, title="¡Compra!", message="¡Cruce de EMAs alcista!")
alertcondition(bearishCross, title="¡Vende!", message="¡Cruce de EMAs bajista!")

// Etiquetas de "Comprar" y "Vender"
var buySignal = bullishCross
var sellSignal = bearishCross
buySignal := buySignal and (close > out2)
sellSignal := sellSignal and (close < out2)
plotshape(buySignal, style=shape.arrowup, location=location.belowbar, color=color.green, title="Comprar")
plotshape(sellSignal, style=shape.arrowdown, location=location.abovebar, color=color.red, title="Vender")


cuando le indico actualizar en el grafico, no muestra ni los cruces ni las etiquetas y mucho menos genera las alertas

[gu5tavo71]

Hola

• Para diferenciar entre bullishCross y bearishCross, debes reemplazar cross por crossover

• No es necesario que reasignes las variables buySignal y sellSignal

Con eso estaría arreglado. Pero te doy un par de consejos mas:

• transp=0 no se usa mas.

• v4 es obsoleto. Escribe en @version=5. Podes usar el conversor del editor

• shape.arrowup y shape.arrowdown son diminutos. Debes acompañarlos de size.normal

Entonces, tu codigo (en v4), quedaría así:

Código: Seleccionar todo

//EMAS CRUCE by RV
//@version=4
study(title="EMAS RV", shorttitle="EMAS RV", overlay=true)
len = input(8, minval=1, title="EMA Azul (8)")
src = input(close, title="Cerrada")
out = ema(src, len)
plot(out, color=#2facc0, transp=0, linewidth=3, title="EMA Azul 8")

len2 = input(18, minval=1, title="EMA Roja (18)")
src2 = input(close, title="Cerrada")
out2 = ema(src2, len2)
plot(out2, color=#f19d1f, transp=0, linewidth=3, title="EMA Roja 18")

len3 = input(200, minval=1, title="EMA Blanca 200")
src3 = input(close, title="Cerrada")
out3 = ema(src3, len3)
plot(out3, color=#fcfdf4, transp=0, linewidth=3, title="EMA 200 C4L")

// Alertas de cruce de EMAs
bullishCross = crossover(out, out2)
bearishCross = crossover(out2, out)
alertcondition(bullishCross, title="¡Compra!", message="¡Cruce de EMAs alcista!")
alertcondition(bearishCross, title="¡Vende!", message="¡Cruce de EMAs bajista!")

// Etiquetas de "Comprar" y "Vender"
buySignal  = bullishCross and (close > out2)
sellSignal = bearishCross and (close < out2)
plotshape(buySignal,  style = shape.arrowup,   location = location.belowbar, color = color.green, title = "Comprar", size = size.normal)
plotshape(sellSignal, style = shape.arrowdown, location = location.abovebar, color = color.red,   title = "Vender",  size = size.normal)